zsh auto completion

[mvgrimes]

Just sharing my zsh autocomplete for the sqitch command. I find this incredibly helpful to complete database targets (-t) and the deployment scripts. I am certainly no expert with auto complete, so improvements are welcome. Hope some else finds this useful.

#compdef sqitch
#autoload

_sqitch () {
  local context state state_descr line
  typeset -A opt_args

  _arguments -C \
    "-h[Show help]" \
    "--help[Show help]" \
    "--man[Show help]" \
    "--etc-path[Set etc]" \
    "--version[Show version]" \
    "-t[database to which to connect]:target:_targets" \
    "--target[database to which to connect]:target:_targets" \
    "1:sqitch commands:_sqitch_commands"  \
    "*::arguments:->args" && ret=0

  case $state in
    args)                       # from ->args
      _sqitch_complete_command_args $line[1]
      ;;
  esac

}

_sqitch_commands() {
    local -a subcommands
    subcommands=(
      "add:Add a new change to the plan"
      "bundle:Bundle a Sqitch project for distribution"
      "checkout:Revert, checkout another VCS branch, and re-deploy changes"
      "config:Get and set local, user, or system options"
      "deploy:Deploy changes to a database"
      "engine:Manage database engine configuration"
      "help:Display help information about Sqitch commands"
      "init:Initialize a project"
      "log:Show change logs for a database"
      "plan:Show the contents of a plan"
      "rebase:Revert and redeploy database changes"
      "revert:Revert changes from a database"
      "rework:Duplicate a change in the plan and revise its scripts"
      "show:Show information about changes and tags, or change script contents"
      "status:Show the current deployment status of a database"
      "tag:Add or list tags in the plan"
      "target:Manage target database configuration"
      "upgrade:Upgrade the registry to the current version"
      "verify:Verify changes to a database"
    )
    _describe -t commands 'sqitch' subcommands
}

_sqitch_complete_command_args() {
  local cmd="$1"

  # Run the completion for the subcommand
  case "${cmd}" in
    verify)
      _arguments : \
        "-t[database to which to connect]:target:_targets" \
        "--target[database to which to connect]:target:_targets"
      _sqitch_complete_entries
      ;;
    revert)
      _arguments : \
        "-t[database to which to connect]:target:_targets" \
        "--target[database to which to connect]:target:_targets"
      _sqitch_complete_entries
      ;;
    add)
      _sqitch_complete_entries
      ;;
    deploy)
      _arguments : \
        "-t[database to which to connect]:target:_targets" \
        "--target[database to which to connect]:target:_targets"
      _sqitch_complete_entries
      ;;
    status)
      _arguments : \
        "-t[database to connect]:target:_targets" \
        "--target[database to which to connect]:target:_targets" \
        "--show-changes[include a list of deployed changes]"
      _sqitch_complete_entries
      ;;
  esac
}

_sqitch_complete_entries() {
  local IFS=$'\n'
  local prefix
  prefix="./deploy"
  _values -C 'change' ${$(find -L "$prefix" -type f -print 2>/dev/null | sed -e "s#${prefix}/\{0,1\}##" -e 's#\.sql##' -e 's#\\#\\\\#' | sort):-""}
}

_targets() {
  local IFS=$'\n'
  _values 'target' ${$(perl -nE'm{^\[target "([^"]+)"} && say $1' sqitch.conf | sort):-""}
}

_sqitch

[theory]

Sweet! Can you add instructions or a link for how to install and use them? Thanks!

[mvgrimes]

I think you can save that file as _sqitch anywhere in your $fpath. That can be different depending on your zsh setup, possibly:

oh-my-zsh

~/.oh-my-zsh/completions/_sqitch
$ZSH_CUSTOM/completions/_sqitch 

plain zsh

~/.zsh/completions/_sqitch
~/.config/zsh/completions/_sqitch

Then I think you can run some compinit command to activate it, but I find it easier to just exec zsh.

[theory]

Very nice, thank you! I added them to theory/oh-my-zsh-theory@911a263.