-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathzpy.plugin.zsh
2981 lines (2522 loc) · 91.2 KB
/
zpy.plugin.zsh
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
autoload -Uz zargs
zmodload -mF zsh/files 'b:zf_(chmod|ln|mkdir|rm)'
zmodload zsh/pcre 2>/dev/null || true
zmodload zsh/mapfile
ZPY_SRC=${0:P}
ZPY_PROCS=${${$(nproc 2>/dev/null):-$(sysctl -n hw.logicalcpu 2>/dev/null)}:-4}
(( ZPY_PROCS*=2 ))
## User may want to override these:
: ${ZPY_VENVS_HOME:=${XDG_DATA_HOME:-~/.local/share}/venvs}
## Each project is associated with: $ZPY_VENVS_HOME/<hash of proj-dir>/<venv-name>
## <venv-name> is one or more of: venv, venv-pypy, venv-<pyver>
## $(venvs_path <proj-dir>) evals to $ZPY_VENVS_HOME/<hash of proj-dir>
: ${ZPY_PIPZ_PROJECTS:=${XDG_DATA_HOME:-~/.local/share}/python}
: ${ZPY_PIPZ_BINS:=${${XDG_DATA_HOME:-~/.local/share}:P:h}/bin}
## Installing an app via pipz puts requirements.{in,txt} in $ZPY_PIPZ_PROJECTS/<appname>
## and executables in $ZPY_PIPZ_BINS
# Optional launcher for all zpy functions as subcommands
.zpy_ui_zpy () { # <function> [<function-arg>...]
emulate -L zsh
local REPLY
.zpy_help
local lines=(${(f)REPLY})
local cmds=(${${(M)lines:#[^# ]*}/ *})
cmds=(${cmds:#zpy})
local subcmds=()
if ! { zstyle -a :zpy: subcommands subcmds } {
local ui_cmd
for ui_cmd ( $cmds ) {
.zpy_help $ui_cmd
lines=(${(f)REPLY})
subcmds+=($ui_cmd ${lines[1]### })
}
zstyle ':zpy:*' subcommands $subcmds
}
case $1 {
subcommands)
rEpLy=($subcmds)
return
;;
--help)
.zpy_ui_help ${0[9,-1]}
return
;;
*)
if (( ${(k)subcmds[(I)$1]} )) {
.zpy_ui_${1} ${@[2,-1]}
return
}
;;
}
return 1
}
## Syntax highlighter, reading stdin.
.zpy_hlt () { # <syntax>
emulate -L zsh
[[ $1 ]] || return
rehash
if [[ -v NO_COLOR ]] {
>&1
return
}
if [[ $1 == diff ]] {
local diffhi args=()
for diffhi ( riff diffr delta diff-so-fancy colordiff ) {
if (( $+commands[$diffhi] )) {
if [[ $diffhi == riff ]] args+=(--no-pager)
if [[ $diffhi == delta ]] args+=(--paging never --color-only)
# delta will use BAT_THEME
BAT_THEME=${BAT_THEME:-ansi} \
$diffhi $args 2>/dev/null
return
}
}
}
if (( $+commands[highlight] )) {
# recommended themes: aiseered, blacknblue, bluegreen, ekvoli, navy
# highlight has two issues with newlines:
# Firstly, empty input can yield unwanted newlines as output.
# https://gitlab.com/saalen/highlight/-/issues/147
# This can be avoided in highlight >= 3.56 with: --no-trailing-nl=empty-file
# Example:
# local lines=(${(f)"$(highlight --version)"})
# local version_words=(${(z)lines[1]})
# if [[ $version_words[-1] -ge 3.56 ]] {
# HIGHLIGHT_OPTIONS=${HIGHLIGHT_OPTIONS:-'-s aiseered'} \
# highlight --no-trailing-nl=empty-file -O truecolor --stdout -S $1
# } else {
# <uncommented method below>
# }
# Secondly, when used multiple times in parallel (via zargs),
# highlight may fail to add a newline at the end of an output,
# resulting in the last line of one doc being joined with
# the first of the next. This is true of at least highlight 3.58.
# The method below bypasses both issues consistently
# across all known versions of highlight, and still outperforms the rest:
local content=$(<&0)
if [[ $content ]] {
local themes=(aiseered blacknblue bluegreen ekvoli navy)
HIGHLIGHT_OPTIONS=${HIGHLIGHT_OPTIONS:-"-s $themes[RANDOM % $#themes + 1]"} \
highlight -O truecolor --stdout --force -S $1 <<<$content
}
} elif (( $+commands[gat] )) { # recommended themes: base16-snazzy, doom-one, gruvbox, onedark, vulcan
GAT_THEME=${GAT_THEME:-doom-one} \
gat --force-color -l $1
} elif (( $+commands[bat] )) { # recommended themes: ansi, zenburn
BAT_THEME=${BAT_THEME:-ansi} \
bat --color always --paging never -p -l $1
} elif (( $+commands[batcat] )) {
BAT_THEME=${BAT_THEME:-ansi} \
batcat --color always --paging never -p -l $1
} elif (( $+commands[rich] )) {
local content=$(<&0)
if [[ $content ]] rich --force-terminal --guides --max-width $(( COLUMNS-4 )) --lexer $1 - <<<$content
} else {
>&1
}
}
## fallback basic pcregrep-like func for our needs; not preferred to pcre2grep or ugrep,
## but maybe preferred to ripgrep, which had a relevant bug before its 14.0.0 release
.zpy_zpcregrep () { # <output> <pattern> <file>
emulate -L zsh
# <output> like: '$1$4$5$7'
local backrefs=() pattern=$2 body=${mapfile[$3]}
backrefs=(${(s:$:)1})
local result_parts=() result_template
result_parts=("\$match[${(@)^backrefs}]")
result_template=${(j::)result_parts} # '$match[1]$match[4]$match[5]$match[7]'
local all_results=() ZPCRE_OP
pcre_compile -m $pattern
pcre_match -b -- $body
while (( ! ? )) {
all_results+="${(e)result_template}"
pcre_match -b -n ${${(z)ZPCRE_OP}[-1]} -- $body
}
print -r -- ${(F)all_results}
}
.zpy_help () { # [<zpy-function>...]
emulate -L zsh -o extendedglob
unset REPLY
# Multiple commands or subcommands:
if (( $# > 1 )) {
local reply
.zpy_all_replies .zpy_help $@
REPLY=${(pj:\n\n:)reply}
return
}
# Either all commands or a single command or subcommand:
local topic=help-${1:-all}
if { zstyle -s :zpy: $topic REPLY } return
[[ -r $ZPY_SRC ]] || return
local cmds_pattern='^(?P<predoc>\n?(# .*\n)*)(\.zpy_ui_(?P<fname>[^._ \n][^ \n]+) \(\) \{)( #(?P<usage> .+))?'
local subcmd_pattern='.* # (?P<usage>.*) ## subcmd: <CMD> <SUBCMD>(?P<postdoc>\n( *# [^\n]+\n)*)'
local cmd_doc=() subcmd_doc=()
rehash
if (( $+commands[ugrep] )) {
cmd_doc=(ugrep -P --format='%[predoc]#%[fname]#%[usage]#%~')
subcmd_doc=(ugrep -P --format='%[usage]#%[postdoc]#%~')
} elif (( $+commands[pcre2grep] )) {
cmd_doc=(pcre2grep -M -O '$1$4$6')
subcmd_doc=(pcre2grep -M -O '$1$2')
} elif { zmodload -e zsh/pcre } {
cmd_doc=(.zpy_zpcregrep '$1$4$6')
subcmd_doc=(.zpy_zpcregrep '$1$2')
} elif (( $+commands[pcregrep] )) {
cmd_doc=(pcregrep -M -o1 -o4 -o6)
subcmd_doc=(pcregrep -M -o1 -o2)
} elif (( $+commands[rg] )) {
cmd_doc=(rg --no-config --color never -NU -r '$predoc$fname$usage')
subcmd_doc=(rg --no-config --color never -NU -r '$usage$postdoc')
} else {
.zpy_log error \
'zpy documentation functions require a search tool' 'Any one of:' \
'- zsh built with --enable-pcre' \
'- rg (ripgrep >=14.0.0)' \
'- ugrep' \
'- pcre2grep (pcre2/pcre2-tools)' \
'- pcregrep (pcre/pcre-tools)'
.zpy_log tip Suggestion "Install ugrep with your distro's package manager."
return 1
}
# All commands or single command (but not a subcommand):
if [[ ! $1 ]] || (( ! ${1[(I) ]} )) {
if [[ $1 ]] cmds_pattern=${(S)cmds_pattern//name>*\)/name>$1)}
zstyle ':zpy:*' $topic ${"$(
$cmd_doc $cmds_pattern $ZPY_SRC
)"##[[:space:]]#}
zstyle -s :zpy: $topic REPLY
return
}
# Subcommand ("<cmd> <subcmd>"):
local cmd subcmd
cmd=${${(z)1}[1]}
subcmd=${${(z)1}[2]}
local lines=(${(f)"$(
$subcmd_doc ${${subcmd_pattern:gs/<CMD>/$cmd}:gs/<SUBCMD>/$subcmd} $ZPY_SRC
)"})
local help_subcmd=()
local -A rEpLy
.zpy_ui_${cmd} subcommands
help_subcmd+=("# ${rEpLy[$subcmd]}" "$cmd $subcmd $lines[1]" $lines[2,-1])
zstyle ':zpy:*' $topic ${(F)help_subcmd##[[:space:]]#}
zstyle -s :zpy: $topic REPLY
}
# Print description and arguments for all or specified functions.
.zpy_ui_help () { # [<zpy-function>...]
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
local REPLY ret=0
.zpy_help $@ || ret=$?
REPLY=${REPLY/$'\n'help /$'\n'zpy help }
REPLY=${REPLY/$'\n'mkbin /$'\n'zpy mkbin }
.zpy_hlt zsh <<<$REPLY || ret=$?
return ret
}
.zpy_path_hash () { # <path>
emulate -L zsh
unset REPLY
[[ $1 ]] || return
rehash
if (( $+commands[md5sum] )) {
REPLY="${$(md5sum =(<<<${1:P}))%% *}"
} else {
REPLY="$(md5 -qs ${1:P})"
}
[[ $REPLY ]] || return
}
.zpy_venvs_path () { # [<proj-dir>]
emulate -L zsh
unset REPLY
[[ $ZPY_VENVS_HOME ]] || return
.zpy_path_hash ${${1:-$PWD}:P} || return
REPLY="${ZPY_VENVS_HOME}/${REPLY}"
}
.zpy_fzf_cmd () {
emulate -L zsh
unset REPLY
local fzf_cmd=fzf
if (( $+commands[fzf] )) {
REPLY=fzf
} elif (( $+commands[sk] )) {
REPLY=sk
} else {
.zpy_log error \
'zpy selection operations require a filter tool' 'Any one of:' \
'- fzf' \
'- sk (skim)'
.zpy_log tip Suggestion "Install fzf with your distro's package manager."
return 1
}
}
.zpy_chooseproj () { # [--multi]
emulate -L zsh
[[ $ZPY_VENVS_HOME ]] || return
# TODO: should this absorb .zpy_pipzchoosepkg?
.zpy_fzf_cmd || return
local fzf_cmd=$REPLY
local multi fzf_args=(--layout=reverse-list -0 --preview='<{}/*.in')
if [[ $1 == --multi ]] {
unset reply
fzf_args+=(-m)
multi=1
shift
} else {
unset REPLY
local reply
}
local projdirs=(${ZPY_VENVS_HOME}/*/project(@N-/:P))
reply=(${(f)"$(
print -rln -- $projdirs \
| SHELL==zsh $fzf_cmd $fzf_args
)"})
[[ $reply ]] || return
if [[ ! $multi ]] REPLY=$reply[1]
}
# Get path of folder containing all venvs for the current folder or specified proj-dir.
# Pass -i to interactively choose the project.
.zpy_ui_venvs_path () { # [-i|<proj-dir>]
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
local REPLY
if [[ $1 == -i ]] {
.zpy_chooseproj || return
.zpy_ui_venvs_path $REPLY
} else {
.zpy_venvs_path $@ || return
print -rn -- $REPLY
}
}
.zpy_please_activate () { # [not-found-item]
emulate -L zsh
.zpy_log error 'FAILED to find' "$1" \
"${${PWD:P}/%${PWD:P:t}/%B${PWD:P:t}%b}"
.zpy_log tip Suggestion "Activate a venv with 'activate' (or 'a8'), first."
}
.zpy_warn_venv () { # [-q]
emulate -L zsh
if ! [[ $VIRTUAL_ENV ]] {
if ! [[ $1 == -q ]] .zpy_please_activate venv
return 1
}
}
# Install and upgrade packages.
.zpy_ui_pipi () { # [--no-upgrade] [<pip install arg>...] <pkgspec>...
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
.zpy_warn_venv || return
local upgrade=-U
if [[ $1 == --no-upgrade ]] { unset upgrade; shift }
if [[ ! $1 ]] { .zpy_ui_help ${0[9,-1]}; return 1 }
rehash
if (( $+commands[uv] )) {
uv pip install -p python $upgrade $@
} else {
python -m pip --disable-pip-version-check install $upgrade $@
}
local ret=$?
rehash
if (( ret )) {
local log_args=(error "FAILED ${0[9,-1]} call" "${0[9,-1]} $@" $VIRTUAL_ENV)
if [[ $VIRTUAL_ENV ]] && [[ -L ${VIRTUAL_ENV:h}/project ]] {
log_args+=${${:-${VIRTUAL_ENV:h}/project}:P:t}
}
.zpy_log $log_args
return ret
}
}
.zpy_print_action () { # [--proj <folder>] <action> <output> [<input>...]
emulate -L zsh
local proj=$PWD
if [[ $1 == --proj ]] { proj=$2; shift 2 }
proj=${${proj:P}/#~\//\~/}
[[ $2 && $1 ]] || return
local action output input=()
action=$1; shift
output=${1/#~\//\~/}; shift
input=(${@/#~\//\~/})
local -A c=(
default cyan
proj blue
syncing green
compiling magenta
appending yellow
creating yellow
injecting yellow
)
if ! (( $+c[$action] )) c[$action]=$c[default]
local parts=()
if ! [[ -v NO_COLOR ]] {
parts+=(
"%F{$c[default]}==>"
"%B%F{$c[$action]}$action%b"
)
if [[ $input ]] parts+=("%F{$c[default]}${(j:%B|%b:)input}")
parts+=(
"%F{$c[$action]}%B->%b"
"%F{$c[default]}$output"
"%F{$c[proj]}%B::%b ${proj/%${proj:t}/%B${proj:t}%b}%f"
)
} else {
parts+=('>' "%B$action%b")
if [[ $input ]] parts+=("${(j:%B|%b:)input}")
parts+=(
'%B->%b' "$output" '%B::%b'
"${proj/%${proj:t}/%B${proj:t}%b}"
)
}
print -rPu2 -- $parts
}
# Install packages according to all found or specified requirements.txt files (sync).
.zpy_ui_pips () { # [<reqs-txt>...]
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
rehash
.zpy_warn_venv || return
if (( ! $+commands[uv] )) && (( ! $+commands[pip-sync] )) {
.zpy_log error 'FAILED to find' 'uv or pip-sync'
.zpy_log tip Suggestion 'pipz install uv'
return 1
}
local reqstxts=(${@:-*requirements.txt(N)}) ret
if [[ $reqstxts ]] {
local p_a_args=(syncing env $reqstxts)
if [[ $VIRTUAL_ENV && -L ${VIRTUAL_ENV:h}/project ]] p_a_args=(--proj ${VIRTUAL_ENV:h}/project(:P) $p_a_args)
.zpy_log action $p_a_args
if (( ! $+commands[uv] )) {
# --read-relative-to-input
pip-sync -q --pip-args --disable-pip-version-check $reqstxts
} else {
uv -q pip sync -p python --allow-empty-requirements $reqstxts
}
ret=$?
local reqstxt #
for reqstxt ( $reqstxts ) { # can remove if pip-tools #896 is resolved
.zpy_ui_pipi --no-upgrade -qr $reqstxt # (by merging pip-tools #907)
if (( ? )) ret=1 #
} #
rehash
if (( ret )) {
.zpy_log error "FAILED ${0[9,-1]} call" "${0[9,-1]} $@"
return ret
}
}
}
.zpy_pipc () { # [--faildir <faildir>] [--snapshotdir <snapshotdir>] <reqs-in> [<pip-compile-arg>...]
emulate -L zsh
rehash
local faildir snapshotdir
while [[ $1 == --(fail|snapshot)dir ]] {
if [[ $1 == --faildir ]] { faildir=${2:a}; shift 2 }
if [[ $1 == --snapshotdir ]] { snapshotdir=${2:a}; shift 2 }
}
if { ! .zpy_warn_venv -q } || (( ! $+commands[uv] && ! $+commands[pip-compile] )) {
.zpy_please_activate "uv or pip-compile"
if [[ $faildir ]] print -n >>$faildir/${PWD:t}
return 1
}
if ! [[ $1 ]] {
if [[ $faildir ]] print -n >>$faildir/${PWD:t}
return 1
}
local reqsin=$1; shift
local reqstxt
if [[ ${reqsin:t:r} ]] {
reqstxt=${reqsin:r}.txt
} else {
reqstxt=${reqsin}.txt
}
local outswitch
for outswitch ( -o --output-file ) {
# TODO: handle --output-file=path form as well
if (( ${@[(I)$outswitch]} )) {
reqstxt=${@[$@[(i)$outswitch]+1]}
break
}
}
.zpy_log action compiling $reqstxt $reqsin
if [[ $snapshotdir ]] {
local origtxt=${snapshotdir}${reqstxt:a}
zf_mkdir -p -m 0700 ${origtxt:h}
if [[ -r $reqstxt ]] {
<$reqstxt >$origtxt
} else {
print -n >$origtxt
}
zf_chmod 0600 $origtxt
}
# Set cache dir for concurrency (see pip-tools #1083):
local REPLY reqstxt_hash cachedir
.zpy_path_hash $reqstxt
reqstxt_hash=$REPLY
cachedir=${VIRTUAL_ENV:-$(mktemp -d)}/zpy-cache/${reqstxt_hash}
local pipcompile_args
if ! { zstyle -a :zpy: pip-compile-args pipcompile_args } pipcompile_args=(
--no-header
--annotation-style=line
--strip-extras
--allow-unsafe
)
# After updating minimum pip-tools to support each of these, add them:
# --write-relative-to-output
# --read-relative-to-input
pipcompile_args=(--cache-dir=$cachedir -o $reqstxt $pipcompile_args $@ $reqsin)
local badrets
if (( $+commands[uv] )) {
pipcompile_args=(--python python ${pipcompile_args:#--(allow-unsafe|strip-extras)})
uv pip compile $pipcompile_args 2>&1
} else {
pip-compile $pipcompile_args 2>&1 \
| .zpy_hlt ini
}
badrets=(${pipestatus:#0})
if [[ $badrets && $faildir ]] print -n >>$faildir/${PWD:t}
[[ ! $badrets ]]
}
.zpy_pipu () { # [--faildir <faildir>] [--snapshotdir <snapshotdir>] <reqsin> [<pkgspec>...] [-- <pip-compile-arg>...]
emulate -L zsh
local zpypipc_args=() pipcompile_args=()
while [[ $1 == --(fail|snapshot)dir ]] {
zpypipc_args+=($1 $2); shift 2
}
if (( ${@[(I)--]} )) {
pipcompile_args+=(${@[$@[(i)--]+1,-1]})
shift -p "$(( $#pipcompile_args+1 ))"
}
[[ $1 ]] || return
local reqsin=$1; shift
local reqs=($@) reqstxt
if [[ ${reqsin:t:r} ]] {
reqstxt=${reqsin:r}.txt
} else {
reqstxt=${reqsin}.txt
}
.zpy_maximum_piptools
.zpy_pipc $zpypipc_args $reqsin -q ${${${reqs/*/-P}:^reqs}:--U} $pipcompile_args
local ret=$?
return ret
}
# Compile requirements.txt files from all found or specified requirements.in files (compile).
# Use -h to include hashes, -u dep1,dep2... to upgrade specific dependencies, and -U to upgrade all.
.zpy_ui_pipc () { # [-h] [-U|-u <pkgspec>[,<pkgspec>...]] [<reqs-in>...] [-- <pip-compile-arg>...]
emulate -L zsh
unset REPLY
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
[[ $ZPY_PROCS ]] || return
local gen_hashes upgrade upgrade_csv
while [[ $1 == -[hUu] ]] {
if [[ $1 == -h ]] { gen_hashes=--generate-hashes; shift }
if [[ $1 == -U ]] { upgrade=1; shift }
if [[ $1 == -u ]] { upgrade=1; upgrade_csv=$2; shift 2 }
}
local pipcompile_args=()
if (( ${@[(I)--]} )) {
pipcompile_args+=(${@[$@[(i)--]+1,-1]})
shift -p "$(( $#pipcompile_args+1 ))"
}
local snapshotdir=$(mktemp -d) faildir=$(mktemp -d) failures=()
local zpypipc_args=(--faildir $faildir --snapshotdir $snapshotdir) # for either .zpy_pipc or .zpy_pipu
if [[ $upgrade ]] {
zargs -P $ZPY_PROCS -ri___ \
-- ${@:-*requirements.in(N)} \
-- .zpy_pipu $zpypipc_args ___ ${(s:,:)upgrade_csv} -- $gen_hashes $pipcompile_args
} else {
zargs -P $ZPY_PROCS -ri___ \
-- ${@:-*requirements.in(N)} \
-- .zpy_pipc $zpypipc_args ___ $gen_hashes $pipcompile_args
}
failures=($faildir/*(N:t))
zf_rm -rf $faildir
.zpy_diffsnapshot $snapshotdir
REPLY=${snapshotdir:a}
if [[ $failures ]] {
.zpy_log error 'Problems compiling' $failures
.zpy_ui_help ${0[9,-1]}
return 1
}
}
# TODO: move highest level funcs to top
# .zpy_log tip <title> <subject> [<line>]...
# .zpy_log error <title> <subject> [<line>]...
# .zpy_log action [--proj <folder>] <action> <output> [<input>...]
.zpy_log () { # tip|error|action <arg>...
emulate -L zsh
case $1 {
action)
shift
.zpy_print_action $@
return
;;
tip)
shift
local title_color=green
local subject_color=blue
;;
error)
shift
local title_color=red
local subject_color=yellow
;;
}
local title="==> $1:"; shift
local subject=${1/#~\//\~/}; shift
local lines=(' '${^@/#~\//\~/})
if ! [[ -v NO_COLOR ]] {
title="%F{$title_color}$title %F{$subject_color}$subject"
lines[-1]="${lines[-1]}%f"
} else {
title="$title $subject"
}
print -lrPu2 -- $title $lines
}
# Compile, then sync.
# Use -h to include hashes, -u dep1,dep2... to upgrade specific dependencies, and -U to upgrade all.
.zpy_ui_pipcs () { # [-h] [-U|-u <pkgspec>[,<pkgspec>...]] [--only-sync-if-changed] [<reqs-in>...] [-- <pip-compile-arg>...]
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
local only_sync_if_changed pipc_args=()
while [[ $1 == (-[hUu]|--only-sync-if-changed) ]] {
if [[ $1 == -[hU] ]] { pipc_args+=($1); shift }
if [[ $1 == -u ]] { pipc_args+=($1 $2); shift 2 }
if [[ $1 == --only-sync-if-changed ]] { only_sync_if_changed=$1; shift }
}
local pipcompile_args=()
if (( ${@[(I)--]} )) {
pipcompile_args=(${@[$@[(i)--]+1,-1]})
shift -p "$(( $#pipcompile_args+1 ))"
}
pipc_args+=($@ ${pipcompile_args:+--} $pipcompile_args)
local do_sync
if [[ ! $only_sync_if_changed ]] do_sync=1
local ret REPLY snapshot
.zpy_ui_pipc $pipc_args
ret=$?
snapshot=$REPLY
if (( ret )) {
.zpy_log error "FAILED ${0[9,-1]} call" "${0[9,-1]} $only_sync_if_changed $pipc_args"
return ret
}
local origtxts=(${snapshot}/**/*(DN.))
local newtxts=(${origtxts#$snapshot})
if [[ ! $do_sync ]] {
local origtxt newtxt
for origtxt newtxt ( ${origtxts:^newtxts} ) {
if ! { diff -q $origtxt $newtxt &>/dev/null } {
do_sync=1
break
}
}
}
if [[ $do_sync ]] .zpy_ui_pips $newtxts
}
# Add loose requirements to [<category>-]requirements.in (add).
.zpy_ui_pipa () { # [-c <category>] <pkgspec>...
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
local reqsin=requirements.in
if [[ $1 == -c ]] { reqsin=${2}-requirements.in; shift 2 }
if [[ ! $1 ]] { .zpy_ui_help ${0[9,-1]}; return 1 }
.zpy_log action appending $reqsin
local lines=(${(f)mapfile[$reqsin]})
for 1 {
if (( lines[(I)$1] )) {
.zpy_log action 'skipping existing entry' $1
} else {
print -rl -- $1 >>$reqsin
}
}
.zpy_hlt ini <$reqsin
}
# Add to requirements.in, then compile it to requirements.txt (add, compile).
# Use -c to affect categorized requirements, and -h to include hashes.
.zpy_ui_pipac () { # [-c <category>] [-h] <pkgspec>... [-- <pip-compile-arg>...]
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
local catg gen_hashes
while [[ $1 == -[ch] ]] {
if [[ $1 == -c ]] { catg=$2; shift 2 }
if [[ $1 == -h ]] { gen_hashes=--generate-hashes; shift }
}
local pipcompile_args=()
if (( ${@[(I)--]} )) {
pipcompile_args+=(${@[$@[(i)--]+1,-1]})
shift -p "$(( $#pipcompile_args+1 ))"
}
if [[ ! $1 ]] { .zpy_ui_help ${0[9,-1]}; return 1 }
local pipa_args=($@) reqsin=requirements.in
if [[ $catg ]] {
pipa_args=(-c $catg $pipa_args)
reqsin=${catg}-requirements.in
}
local pipc_args=($reqsin -- $gen_hashes $pipcompile_args)
.zpy_ui_pipa $pipa_args
.zpy_ui_pipc $pipc_args
}
# Add to requirements.in, compile it to requirements.txt, then sync to that (add, compile, sync).
# Use -c to affect categorized requirements, and -h to include hashes.
.zpy_ui_pipacs () { # [-c <category>] [-h] <pkgspec>... [-- <pip-compile-arg>...]
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
.zpy_ui_pipac $@
local ret=$?
if (( ret )) {
.zpy_log error "FAILED ${0[9,-1]} call" "${0[9,-1]} $@"
return ret
}
local reqstxt=requirements.txt
if [[ $1 == -h ]] shift
if [[ $1 == -c ]] reqstxt=${2}-requirements.txt
.zpy_ui_pips $reqstxt
}
# View contents of all *requirements*.{in,txt} files in the current or specified folders.
.zpy_ui_reqshow () { # [<folder>...]
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
[[ $1 ]] || 1=$PWD
local reqsfiles=() rf
for 1 {
# Basically this, but avoiding reliance on tail:
# tail -n +1 $1/*requirements*.{in,txt} | .zpy_hlt ini
reqsfiles+=($1/*requirements*.{txt,in}(N))
for rf ( $reqsfiles ) {
if [[ $rf != ${reqsfiles[1]} ]] print
print -r -- '--' $rf '--'
.zpy_hlt ini <$rf
}
if [[ $1 != ${@[-1]} ]] print
}
}
.zpy_pyvervenvname () {
emulate -L zsh
unset REPLY
rehash
if (( ! $+commands[python] )) {
.zpy_log error 'FAILED to find in path' python
return 1
}
local name=(${(f)"$(python -V 2>&1)"})
name=(${(z)name[-1]})
REPLY=venv-${(j:-:)name:0:2:l:gs/[/}
}
.zpy_envin () { # <venv-name> <venv-init-cmd...> [-- <reqs-txt>...]
emulate -L zsh
[[ $2 && $1 ]] || return
# get venvs path (vpath) and named venv path (venv):
local REPLY vpath venv
.zpy_venvs_path || return
vpath=$REPLY
venv=$vpath/$1; shift # chomp <venv-name>
local reqstxts=() # chomp [-- <reqs-txt>...]:
local cmd_end=${@[(I)--]}
if (( cmd_end )) {
reqstxts=(${@[$cmd_end+1,-1]})
shift -p "$(( $#reqstxts+1 ))"
}
local venv_cmd=($@) # <venv-init-cmd...>
local short_venv
.zpy_shortvenv $venv
short_venv=$REPLY
# create venv if necessary:
local ret
if [[ ! -r $venv/bin/activate ]] {
.zpy_log action creating $short_venv
zf_rm -rf $venv
$venv_cmd $venv
}
ret=$?
if (( ret )) {
.zpy_log error 'FAILED to make venv' "$venv_cmd $venv"
return ret
}
zf_ln -sfn $PWD ${vpath}/project
. $venv/bin/activate || return
.zpy_minimum_piptools || return
.zpy_ui_pips $reqstxts
}
.zpy_argvenv () { # pypy|current -> ($venv_name $venv_cmd...)
emulate -L zsh
unset reply
rehash
local venv_name venv_cmd=()
case $1 {
pypy)
venv_name=venv-pypy
venv_cmd=(pypy3 -m venv)
if (( $+commands[uv] )) venv_cmd=(uv venv -q -p pypy3)
;;
current)
local REPLY
.zpy_pyvervenvname || return
venv_name=$REPLY
local major=$(python -c 'from __future__ import print_function; import sys; print(sys.version_info.major)')
[[ $major == 3 ]] || return
venv_cmd=(python -m venv)
if (( $+commands[uv] )) venv_cmd=(uv venv -q -p python)
;;
*)
return 1
;;
}
reply=($venv_name $venv_cmd)
}
# Activate the venv (creating if needed) for the current folder, and sync
# its installed package set according to all found or specified requirements.txt files.
# In other words: [create, ]activate, sync.
# The interpreter will be whatever 'python3' refers to at time of venv creation, by default.
# Pass --py to use another interpreter and named venv.
.zpy_ui_envin () { # [--py pypy|current] [<reqs-txt>...]
emulate -L zsh
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
rehash
local venv_name=venv venv_cmd=(python3 -m venv)
if (( $+commands[uv] )) venv_cmd=(uv venv -q -p python3)
if [[ $1 == --py ]] {
local reply
if ! { .zpy_argvenv $2 } { .zpy_ui_help ${0[9,-1]}; return 1 }
venv_name=$reply[1]
venv_cmd=($reply[2,-1])
shift 2
}
.zpy_envin $venv_name $venv_cmd -- $@
}
# Activate the venv for the current folder or specified project, if it exists.
# Otherwise create, activate, sync.
# Pass -i to interactively choose the project.
# Pass --py to use another interpreter and named venv.
.zpy_ui_activate () { # [--py pypy|current] [-i|<proj-dir>]
emulate -L zsh -o localtraps
if [[ $1 == --help ]] { .zpy_ui_help ${0[9,-1]}; return }
local envin_args=() venv_name=venv interactive
while [[ $1 == -(i|-py) ]] {
if [[ $1 == -i ]] { interactive=1; shift }
if [[ $1 == --py ]] {
local reply
if ! { .zpy_argvenv $2 } { .zpy_ui_help ${0[9,-1]}; return 1 }
venv_name=$reply[1]
envin_args=($1 $2)
shift 2
}
}
local REPLY
if [[ $interactive ]] {
.zpy_chooseproj || return
.zpy_ui_activate $envin_args "$REPLY"
return
}
local projdir=${${1:-$PWD}:P}
local venv
.zpy_venvs_path $projdir || return
venv=$REPLY/$venv_name
local activator=$venv/bin/activate
if [[ ! -r $activator ]] {
trap "cd ${(q-)PWD}" EXIT INT QUIT
zf_mkdir -p $projdir
cd $projdir
.zpy_ui_envin $envin_args
} elif { . $activator } {
.zpy_minimum_piptools || return
} else {
return
}
}
.zpy_minimum_piptools () {
emulate -L zsh
rehash
if ! (( $+commands[uv] )) {
.zpy_ui_pipi --no-upgrade -q \
'pip-tools>=7.1.0' \
'setuptools>=62.0.0' \
wheel
}
}
.zpy_maximum_piptools () {
emulate -L zsh
rehash